//**************************************************
// Using Dummy Variables in Linear Regression 
// Written by Hun Myoung Park
// March 24, 2005
// Data set: IT_firm04.csv
// http://mypage.iu.edu/~kucc625/method/method.html
//**************************************************

log using "c:\temp\IT_firm04.log, replace"
// insheet using "C:\temp\IT_firm04.csv", comma clear
use http://mypage.iu.edu/~kucc625/archives/IT_firm04.dta, clear

/*
label data "Top 50 ICT firms from OECD 2004"
label var area "Area of Country"
label define area 1 "Asia" 2 "Europ" 3 "America"
label value area area

label var type "Type of Firm"
label define type 1 "Telecom" 2 "Electronics" 3 "IT Equipment" 4 "Comm. Equipment" 5 "Service & S/W"
label value type type

label var rev2000 "Revenue 2000 (USD Millions)"
label var rev2003 "Revenue 2003 (USD Millions)"

label var emp2000 "Employees 2000"
label var emp2002 "Employees 2002"

label var rd2000 "R&D Expenditure 2000 (USD Millions)"
label var rd2002 "R&D Expenditure 2002 (USD Millions)"

label var net2000 "Net Income 2000 (USD Millions)"
label var net2003 "Net Income 2003 (USD Millions)"

save "C:\kucc625\IT_firm04.dta"
*/



//***********************************************************
sum // Descriptive statistics




//***********************************************************
// Dummy variable coding for firm types

gen int d1=0
replace d1=1 if type==1
label var d1 "Telecom Firm?"

gen int d2=0
replace d2=1 if type==2
label var d2 "Electronics?"

gen int d3=0
replace d3=1 if type>=3
label var d3 "Equipment?"

gen d=d3
label var d "Equipment?"

gen int d0=1
replace d0=0 if d3==1
label var d0 "Telecom/Electronics?"

list firm country rd2002 net2000 type d, noobs


//***********************************************************
// Regression for binary categories

regress rd2002 net2000 // Model 1
regress rd2002 net2000 d // Model 2 with a dummy
regress rd2002 net2000 d0 // Model 2-1 with a dummy
regress rd2002 net2000 d d0, nocon // Model 2-2 with two dummy and no intercept

regress rd2002 net2000 if d==1 // Model 1-1
regress rd2002 net2000 if d==0 // Model 1-2


//***********************************************************
// Regression for multiple categories 

list firm rd2000 net2000 type d1 d2 d3, noobs

regress rd2002 net2000 d1 d2 d3, nocon //LSDV1
regress rd2002 net2000 d1 d2 // LSDV2

recode type 1=1 2=2 *=3, gen(type2)
xtreg rd2002 net2000, fe i(type2) //LSDV3



//***********************************************************
// Regression of two-way fixed effects


// Dummy variable coding for area effect 
gen int g1=0
replace g1=1 if area==1
label var g1 "Asian Firms?"

gen int g2=0
replace g2=1 if area==2
label var g2 "European Firms?"

gen int g3=0
replace g3=1 if area==3
label var g3 "American Firms?"

list firm type d1 d2 d3 area g1-g3, noobs



//***********************************************************
// regression of two-way fixed effect model

regress rd2002 net2000 d1-d2 g1-g2

regress rd2002 net2000 d1-d2 // restricted model (type)
regress rd2002 net2000 g1-g2 // restricted model (area)



//***********************************************************
// regression with interaction term
gen inc_d=net2000*d
list firm type rd2002 net2000 inc_d d, noobs

regress rd2002 net2000 inc_d d, noc // different slopes and intercepts

regress rd2002 net2000 inc_d // same intercept and differnt slopes

log close